Vous avez reçu un message "Your GitLab account has been locked ..." ? Pas d'inquiétude : lisez cet article https://docs.gricad-pages.univ-grenoble-alpes.fr/help/unlock/

Commit 681b630a authored by Mathieu Mangeot's avatar Mathieu Mangeot
Browse files

First import

parents
read lexc verb.lexc
define Verb;
read lexc affix.lexc
define Affix;
read lexc pronoun.lexc
define Pronoun;
define PronToneGroup Pronoun;
define Verbs [Verb ({ } Verb)];
define Affixes [Affix ({ } Affix)];
define Space { };
define Word \Space+;
define VerbToneGroup [Verbs ({ } Affixes)];
define Sentence ["|" { } (PronToneGroup { } "|" { }) VerbToneGroup { } "|"];
define VerbTone ˧ -> ˩ || "+Verb" "+La" { } ~{ }+ _ "+Verb" "+Mc";
define SuffixTone ˩ -> ˥ || "+Verb"~{ }+ { } ~{ }+"+Verb"~{ }+ { } ~{ }+ _ "+Desiderative";
define Isolation ˧ -> ˩ || %| { } Word _ Word { } %|;
define AddFirstToneBoundary [..] -> "|" { } || .#. _ ;
define AddLastToneBoundary [..] -> { } "|" || _ .#.;
define AddToneBoundaries AddFirstToneBoundary .o. AddLastToneBoundary ;
define RemoveToneGroupBoundary %| -> 0;
define RemoveMultipleSpaces Space -> 0 || Space _ ;
define RemoveLeadingSpace Space -> 0 || .#. _ ;
define RemoveTrailingSpace Space -> 0 || _ .#. ;
define RemoveTags "+Pron"|"+1SG"|"+Verb"|"+H"|"+Mc"|"+La" -> 0;
define Cleanup RemoveTags .o. RemoveToneGroupBoundary .o. RemoveMultipleSpaces .o. RemoveLeadingSpace .o. RemoveTrailingSpace ;
define Grammar AddToneBoundaries
.o.
Sentence
.o.
Isolation
.o.
SuffixTone
.o.
VerbTone
.o.
Cleanup
;
regex Grammar;
# njɤ˧+Pron+1SG | ʑi˩+Verb+La bi˧+Verb+Mc -zo˧+Obligative -ho˩+Desiderative
# => njɤ˩ ʑi˩ bi˩ -zo˧ -ho˥
\ No newline at end of file
Multichar_Symbols +Pron +1SG
LEXICON Root
njɤ˧ Pronoun;
LEXICON Pronoun
+Pron+1SG #;
\ No newline at end of file
Multichar_Symbols +Verb +H +Mc +La
LEXICON Root
dzu VerbH;
bi˧ VerbMc;
ʑi˩ VerbLa;
LEXICON VerbH
+Verb+H #;
LEXICON VerbMc
+Verb+Mc #;
LEXICON VerbLa
+Verb+La #;
\ No newline at end of file
Markdown is supported
0% or .
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment